home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 / Ham Radio 2000.iso / ham2000 / packet / p_tapr / kissv7 / kiss_v7.mac < prev    next >
Text File  |  1991-06-27  |  49KB  |  1,887 lines
  1. ;
  2. ;             KISS TNC for the TNC-2 and clones
  3. ;
  4. ; k3mc 30 Sep 86 - original version
  5. ;
  6. ; 1 Mar 87.  Fixed all known bugs.  Re-arrange code to allow ROMing (this
  7. ; means that data areas need to be initialized from the code).  Figure out the
  8. ; Stack Pointer given the amount of available RAM.  Include the codes 05 00
  9. ; and 05 01 to mean full duplex off and full duplex on, respectively.
  10. ; Clear out all available RAM.  Do a "dance" with LEDs when initially booted:
  11. ; Flash the LED(s) for about 5 seconds such that CON only flashes if you have
  12. ; 8k RAM, STA only flashes if 16k RAM, and STA and CON flash if 32k RAM.
  13. ;
  14. ; 29 Mar 87. Add code to discard BREAK chars, and chars with framing errors.
  15. ; Fix bug in ib_rca which did not discard null received frames.
  16. ;
  17. ; 11 Dec 89.  Incorporate code from Jan Schiefer, DL5UE, [44.130.48.9]
  18. ; Degerlocherstrasse 5, 7000 Stuttgart 70, Federal republic of Germany
  19. ; to fix the problem with Full-Duplex operation.  New version number, v.4
  20. ;
  21. ; 19 Jan 91. Shin-ichi Kanno , JN1JDZ , [133.168.32.129]
  22. ; Fix the DCD detection problem. Add the auto-enable operation.
  23. ; Add the code of output following data routine. New version number, v.5
  24. ;
  25. ; 27 Jun 91. Add the TXdelay control . Fix buffer allocation problem .
  26. ; Add the code of Software DCD Detection routine. New version number, v.7
  27. ;
  28.  
  29. FALSE    equ    0
  30. TRUE    equ    NOT FALSE
  31.  
  32. ALONE    equ    TRUE    ;uncomment this line to get stand-alone code. 
  33.  
  34. ;TASCO    equ    TRUE    ;uncomment this line to get for TASCO's TNC's
  35.             ;(TNC-20,TNC-20H and TNC-22) ROM code.
  36.  
  37. SIO_AUTO    equ    TRUE    ;uncomment this line to set SIO PORT B for
  38.                 ;auto-enable mode.
  39.  
  40. HARDWARE    equ    TRUE    ;uncomment this line to add the set hardware
  41.                 ;sub command.
  42.  
  43.  
  44. ;    .z80
  45. ;    aseg
  46. ;    org    100h    ;silly stuff for CP/M...
  47.  
  48.     ifdef    ALONE
  49.             .phase    0000h
  50. Free_RAM        equ    8000h
  51.     else
  52.         ifdef    TASCO
  53.             .phase    7000h
  54. Free_RAM        equ    0d000h
  55.         else
  56.             .phase    7800h
  57. Free_RAM        equ    9000h
  58.         endif
  59.     endif
  60.  
  61. SIO    equ    0dch        ;actually, only A5 is used for SIO -cs
  62.  
  63. A_dat    equ    SIO+0    ;Modem port
  64. A_ctl    equ    SIO+1    ;Modem port
  65.  
  66. B_dat    equ    SIO+2    ;user serial port
  67. B_ctl    equ    SIO+3    ;user serial port
  68.  
  69. DCD    equ    8        ;Bit in RR0, used in Ch A
  70. CTS    equ    32        ;Bit in RR0, used in Ch A
  71.  
  72. TBE    equ    4        ;TX Buffer Empty bit
  73. RTS    equ    2        ;Request To Send (PTT bit in WR5 of Chan A)
  74.  
  75. Framing_Error    equ    40h    ;Bit in RR1 for async framing error
  76. Break_Abort    equ    80h    ;Bit in RR0 for async Break detection
  77.  
  78.     ifdef SIO_AUTO
  79. Auto_Enable    equ    0e1h
  80.     else
  81. Auto_Enable    equ    0c1h
  82.     endif
  83.  
  84. FEND    equ    300o        ;300 octal
  85. FESC    equ    333o        ;333 octal
  86. TFEND    equ    334o        ;334 octal
  87. TFESC    equ    335o        ;335 octal
  88.  
  89. ALEDon    equ    69h        ;bits for WR5 to turn on  STA LED
  90. ALEDoff    equ    0e9h        ;bits for WR5 to turn off STA LED
  91.  
  92. ALED    equ    80h        ;The DTR Bit in Ch A WR5, we will soon remove
  93.                 ;previous 2 definitions & use the memory loc.
  94.                 ;A_WR5 to hold Ch A WR5's value, because we
  95.                 ;need to be aware when we are transmitting!
  96.  
  97. BLEDon    equ    6ah        ;bits for WR5 to turn on  CON LED
  98. BLEDoff    equ    0eah        ;bits for WR5 to turn off CON LED
  99. BLED    equ    80h
  100.  
  101. start:
  102.     jp    code_start    ;go around this data area
  103. version:
  104.     db    'v.7 27 Jun 91'
  105.     ;13 bytes (exactly!) here for version string
  106.  
  107. I_Vector:
  108.     dw    ib_tbe    ;ch B transmitter buffer empty interrupt/user
  109.     dw    ib_ext    ;ch B ext/status change/user
  110.     dw    ib_rca    ;ch B received char available/user
  111.     dw    ib_special    ;ch B special receive condition/user
  112.  
  113.     dw    ia_tbe    ;ch A transmitter buffer empty interrupt/modem
  114.     dw    ia_ext    ;ch A ext/status change/modem
  115.     dw    ia_rca    ;ch A received char available/modem
  116.     dw    ia_special    ;ch A special receive condition/modem
  117.  
  118. code_start:
  119.     di                ;No interrupts for the moment...
  120.  
  121. ;Init SIO.  This is required even if we wanna flash LEDs...
  122.  
  123.     in    a,(A_ctl)        ;assure we are talking to ch 0
  124.     ld    c,A_ctl
  125.     ld    b,a_size
  126.     ld    hl,a_init
  127.     otir                ;init sync (modem) port
  128.  
  129. ;Init Async port, also to allow flashing LEDs
  130.  
  131.     in    a,(B_ctl)        ;assure we are talking to ch 0
  132.     ld    c,B_ctl
  133.     ld    b,b_size
  134.     ld    hl,b_init
  135.     otir                ;init async port & interrupt vector
  136.  
  137. ; 
  138. ; Figure out where top of stack is, set stack pointer.
  139. ; 32K RAM system.
  140.  
  141.     ld    sp,0            ;[JDZ]
  142.  
  143. ;Clear out RAM.
  144.  
  145.     ld    bc,0ffffh-Free_RAM-1    ;[JDZ] get Byte Count into BC
  146.     ld    hl,Free_RAM        ;[JDZ]
  147.     ld    (hl),0            ;[JDZ]
  148.     ld    de,Free_RAM+1        ;[JDZ] get "source" address = Free_RAM
  149.  
  150.     ldir                ;Zero memory.
  151.  
  152. ;This sequence loads up our data area in RAM:
  153.  
  154.     ld    hl,data_init
  155.     ld    de,TXdelay
  156.     ld    bc,data_size
  157.     ldir
  158.  
  159.  
  160. ; init free buffer list.
  161.  
  162.     ld    hl,Bottom        ;[JDZ] beginning of buffer space
  163.                     ;[JDZ] now it's also top of free list
  164.     ld    b,-1+(-100-Bottom)/128    ;[JDZ] get buffers - 1
  165. ibloop:
  166.     push    hl
  167.     ld    de,128
  168.     add    hl,de            ;HL has "next" pointer
  169.     ex    de,hl            ;DE has "next" pointer
  170.     pop    hl            ;HL now has pointer to current buffer
  171.  
  172.     ld    (hl),e            ;low byte of "next" pointer first
  173.     inc    hl
  174.     ld    (hl),d            ;now hi byte
  175.     inc    hl
  176.     xor    a
  177.     ld    (hl),a            ;zero out count field
  178.     inc    hl
  179.     ld    (hl),a            ;zero out # of bytes read field
  180.  
  181.     ex    de,hl            ;HL is now pointer to next buffer
  182.     djnz    ibloop            ;and init all the available buffers
  183.  
  184.     xor    a
  185.     ld    (hl),a            ;Last "next" address is 0
  186.     inc    hl
  187.     ld    (hl),a            ;ditto
  188.  
  189.     inc    hl
  190.     ld    (hl),a            ;zero out count field
  191.     inc    hl
  192.     ld    (hl),a            ;zero out # of bytes read field
  193.  
  194. ;init regs for ib_ext interrupt
  195.     exx
  196.     ld    bc,0            ;set prev state of SYNC pin,for 1200hz
  197.     ld    de,0            ;count of # of interrupts init
  198.     exx
  199.  
  200. ;[JDZ] Now have the CON and STA LEDs do a "dance".
  201.  
  202.     ld    b,6        ;Do it 6 times (arbitrary as hell, but should
  203.                 ;be an even number so that the LEDs are off at
  204.                 ;the end of this mess...)
  205.     ld    hl,0        ;use HL as downcounter
  206. dance0:
  207.     call    CON_Flip
  208.     call    STA_Flip
  209. dance1:
  210.     dec    hl
  211.     ld    a,h
  212.     or    l
  213.     jr    nz,dance1
  214.  
  215.     djnz    dance0        ;do this 6 times  (3 "cycles")
  216.  
  217. ;Previous stuff showed that the download or boot worked properly...
  218.  
  219.  
  220.  
  221. ;We re-initialize the SIO ports so that we flush garbage chars that may have
  222. ;come in while we were diddling the LEDs.  This is necessary because unless we
  223. ;do this, then the A channel (modem) get RX overrun (esp if TNC was listening
  224. ;to noise) and RX overrun is VERY BAD - so bad, in fact, that I turn on both
  225. ;CON and STA and halt, because this situation should NEVER happen in normal
  226. ;use.  I flush the B (tty) channel in case anything was sent to it in mid-
  227. ;stream.
  228.  
  229.  
  230. ;Re-Init SIO.
  231.  
  232.     in    a,(A_ctl)        ;assure we are talking to ch 0
  233.     ld    c,A_ctl
  234.     ld    b,a_size
  235.     ld    hl,a_init
  236.     otir                ;init sync (modem) port
  237.  
  238. ;Re-Init Async port.
  239.  
  240.     in    a,(B_ctl)        ;assure we are talking to ch 0
  241.     ld    c,B_ctl
  242.     ld    b,b_size
  243.     ld    hl,b_init
  244.     otir                ;init async port & interrupt vector
  245.  
  246. ; Prepare to load hi bits of interrupt vector
  247.  
  248.     ld    a,I_Vector/256
  249.     ld    i,a            ;set interrupt page for mode 2 ints
  250.     im    2
  251.     ei                ;let 'em rip!
  252.  
  253. ;-----------------------------------------------------------------------------
  254. ; This is the background program.
  255. ; Note that since everything else is interrupt driven, and saves registers,
  256. ; this part of the code can use registers & expect values to stay.
  257.  
  258. Commutator_loop:
  259.     call    TX_data
  260.     call    Host_TX_data
  261.     jp    Commutator_loop
  262.  
  263. ;Now see if we need to start an output to RS-232 (host) port
  264. Host_TX_data:
  265.     ld    a,(out_started)
  266.     or    a            ;also clears carry (see below) 
  267.     ret    nz            ;if output started, nothing to do
  268.  
  269.     in    a,(B_ctl)        ;look at RR0
  270.     and    TBE            ;isolate the TBE bit
  271.     ret    z
  272.  
  273. ; else we should check to see if we need to start an output
  274.     di
  275.     call    CON_off            ;
  276.     ld    hl,(out_head_cbuf)    ;grab current top of circ buf ptr
  277.     ld    de,(out_tail_cbuf)    ;and where the next free buf ptr is
  278.     ei
  279.                     ;interrupt protect the pickup of the
  280.                     ;two pointers 3 Feb 87
  281.     or    a
  282.     sbc    hl,de
  283.     ret    z            ;if the same, nothing to do
  284.  
  285. ;else we need to start an output
  286.     di                ;interrupt protect this section,
  287.                     ;although I'm not sure it needs it...
  288.                     ;3 Feb 87
  289.                     ;note: it should already BE done!
  290.     ld    hl,(out_head_cbuf)    ;get pointer to next cbuf to output
  291.     ld    e,(hl)
  292.     inc    hl
  293.     ld    d,(hl)            ;DE has pointer to buffer chain
  294.     ld    (out_chain_head),de    ;set in interrupt routine's place
  295.     ld    a,TRUE
  296.     ld    (out_started),a        ;yes, output started
  297.  
  298.     call    CON_on    
  299.  
  300.     ld    a,FEND
  301.     out    (B_dat),a        ;send FEND character (start txing)
  302.     ei
  303.  
  304.     ret                ;keep looking for new opportunity
  305.  
  306. TX_data:
  307.     ld    a,(TX_State)
  308.     or    a
  309.     jp    z,txd0
  310.     cp    1
  311.     jp    z,txd1
  312.     cp    2
  313.     jp    z,txd2
  314.     cp    3
  315.     jp    z,txd3
  316.     cp    4
  317.     ret    z
  318.  
  319. ;When tail timer times out, turn off the TX
  320.  
  321.     ld    a,(TX_Timer)
  322.     or    a
  323.     ret    nz
  324.  
  325.     ld    a,5        ;ready to write to WR5 of Ch A
  326.     di            ;must have atomic use of A_WR5 & SIO
  327.     out    (A_ctl),a    ;Next char to A_ctl goes to WR5
  328.     ld    a,(A_WR5)    ;grab A_WR5
  329.     and    NOT RTS        ;turn off RTS bit there
  330.     ld    (A_WR5),a    ;keep memory copy updated
  331.     out    (A_ctl),a    ;and turn off TX now
  332.     xor    a
  333.     ld    (TX_State),a
  334.     ei
  335.     ret
  336.  
  337. txd0:
  338.     ld    a,(TX_outstanding)    ;if there are no outstanding TX...
  339.     or    a            ;...frames, then we don't have to...
  340.     ret    z            ;...worry about Transmitter
  341.  
  342. ; do persistence algorithm
  343.     ld    a,r            ;grab the Z-80 refresh register
  344.     add    a,a            ;double;now 0 <= A reg <= 254
  345.     ld    b,a            ;B holds our "random" number
  346.     ld    a,(Persistence)
  347.     sub    b            ;A reg = Persistence - Random #
  348.     jp    c,No_PTT        ;if (P-r) < 0 then no PTT now
  349.                     ; Note that P=255 means ALWAYS key up
  350.  
  351. ; else we've noticed that we've got some frame(s) to send.
  352. ; try to keyup TX
  353.  
  354.     ld    a,(Full_Duplex)
  355.     or    a
  356.     jp    nz,Key_Up        ;if Full Duplex, then there is no
  357.                     ;need to worry about all this silly
  358.                     ;slot time and persistence stuff!
  359.  
  360.     ifdef    HARDWARE
  361. ;check soft DCD.
  362.     ld    a,(Soft_DCD)
  363.     ld    l,a
  364.     bit    1,l
  365.     jp    z,txd1a
  366.  
  367.     ld    a,(RX_State)
  368.     or    a
  369.     jp    nz,No_PTT
  370.  
  371. ;check if Carrier Detect is active
  372. txd1a:
  373.     bit    0,l
  374.     jp    z,Key_Up
  375.  
  376.     endif
  377.  
  378.     ld    a,(A_RR0)        ;A_RR0 is set in interrupt routine
  379.     and    DCD
  380.     jp    nz,No_PTT        ;[JDZ] If carrier active, wait it out
  381.  
  382. ;OK, so we've won with the random number generator.  Keyup TX and start the
  383. ;TXdelay timer
  384.  
  385. Key_Up:
  386.     ld    a,(TXdelay)
  387.     ld    (TX_Timer),a        ;Get timer value into timer slot
  388.  
  389.     ld    a,5
  390.     di                ;we need quite time here.
  391.     out    (A_ctl),a        ;Ready to write into WR5 of Ch A
  392.     ld    a,(A_WR5)
  393.     or    RTS            ;Turn on the PTT bit...
  394.     ld    (A_WR5),a        ;...in the memory copy of WR5
  395.     out    (A_ctl),a        ; Keyup transmitter
  396.     ld    a,2
  397.     ld    (TX_State),a
  398.     ei
  399.     ret                ;That's all we do for now, we await
  400.                     ;TXdelay event
  401.  
  402. No_PTT:    ;since we lost on Random #, wait SlotTime before trying again
  403.     ld    a,(SlotTime)
  404.     ld    (TX_Timer),a        ;Set up the timer value of this event
  405.     ld    a,1
  406.     ld    (TX_State),a
  407.     ret
  408.  
  409. txd1:
  410.     ld    a,(TX_Timer)
  411.     or    a
  412.     ret    nz
  413.     xor    a
  414.     ld    (TX_State),a
  415.     ret
  416.  
  417. txd2:
  418.     ld    a,(TX_Timer)
  419.     or    a
  420.     ret    nz
  421.     ld    a,3
  422.     ld    (TX_State),a
  423.     ret
  424.  
  425. txd3:
  426.     ifdef    HARDWARE
  427. ;    CTS flow
  428.     ld    a,(CTS_Control)
  429.     or    a
  430.     jp    z,txd3a
  431.  
  432.     ld    a,(A_RR0)
  433.     and    CTS
  434.     ret    z
  435. txd3a:
  436.     endif
  437.     di
  438.  
  439.     ld    a,4
  440.     ld    (TX_State),a
  441.  
  442.     call    TXnext_CBuf        ;gets HL to point to buffer chain, and
  443.                     ;sets TX_Chain_Head for the interrupt
  444.                     ;routine
  445.     ld    a,80h
  446.     out    (A_ctl),a        ; reset TX CRC
  447.     call    getchar            ; getchar needs int. protection
  448.     out    (A_dat),a        ; Ship this char to TX modem
  449.     ld    a,TRUE
  450.     ld    (TX_Started),a    ; and, yes Virgina, we've started TX
  451.     ld    a,0c0h
  452.     out    (A_ctl),a        ; reset TX underrun/EOM latch
  453.  
  454.     ei
  455.     ret
  456.  
  457.  
  458. ;    include    IA.MAC            ;Modem interrupt catchers
  459. ;---------------------------------------------------------------------------
  460. ia_tbe:
  461.     push    af
  462.     push    hl
  463.     ld    a,(TX_Started)
  464.     or    a
  465.     jp    z,ia_t2        ; previous frame finished
  466.  
  467.     ld    hl,(TX_Chain_Head)
  468.     call    getchar
  469.     ld    (TX_Chain_Head),hl    ; must keep this pointer updated
  470.     jp    z,ia_t1        ; no more to send
  471.  
  472.     out    (A_dat),a        ; else ship this char out
  473. ia_t9:
  474.     pop    hl
  475.     pop    af
  476.     ei
  477.     reti                ; just return from these interrupts
  478.  
  479. ia_t1:
  480. ;    halt                ;if it gets here, halt
  481.     xor    a
  482.     ld    (TX_Started),a    ; TX is NOT started
  483.     ld    hl,TX_Outstanding    ; make is so that one fewer frames
  484.                     ; NOT "(TX_Outstanding)" (!) 29 Sep
  485.     dec    (hl)            ; are outstanding
  486.     ld    a,28h
  487.     out    (A_ctl),a        ; reset TX interrupt pending
  488.     jp    ia_t9
  489.  
  490. ;previous frame is done, SIO now sending a flag.  More?
  491. ia_t2:
  492.     ld    a,(TX_Outstanding)
  493.     or    a
  494.     jp    nz,ia_t21        ;if more to send, go there
  495.  
  496. ; else we're done here, clean up.
  497.     ld    a,28h
  498.     out    (A_ctl),a        ; Reset TX interrupt pending
  499.  
  500. ;start Tail timer event
  501.     ld    a,(TailTime)
  502.     ld    (TX_Timer),a        ; wait for CRC to clear TX
  503.     ld    a,5
  504.     ld    (TX_State),a
  505.     jp    ia_t9
  506.  
  507. ia_t21:            ;start up next frame
  508.     call    TXnext_CBuf        ; get the next buffer chain pointer
  509.                     ; setup HL and TX_Chain_Head
  510.     ld    a,80h
  511.     out    (A_ctl),a        ; reset TX CRC generator
  512.     call    getchar
  513.     out    (A_dat),a        ;get 1st char of next frame
  514.     ld    a,TRUE
  515.     ld    (TX_Started),a    ; TX started again
  516.     ld    a,0c0h
  517.     out    (A_ctl),a        ; reset TX underrun/EOM latch
  518.     jp    ia_t9
  519.  
  520. ;---------------------------------------------------------------------------
  521. ; Got a character from the SIO RX interrupt, deal with it
  522. ; Extensive mods 3 Feb 87 to be in line with what I now know about SIO...
  523.  
  524. ia_rca:
  525.     push    af
  526.     push    hl
  527.  
  528.     ld    a,(RX_flushing)
  529.     or    a
  530.     jp    z,ia_rc1
  531.  
  532.     in    a,(A_dat)
  533.     jp    ia_rc9
  534.  
  535. ia_rc1:
  536.     ld    a,(RX_Allocated_Buffer)
  537.     or    a
  538.     jp    nz,ia_rc7    ; Go there if we are in "receiving" state
  539.  
  540. ;else we are not yet receiving, so allocate buffer & make us "receiving"
  541.  
  542.     call    allocate_buffer    ; get a new buffer
  543.     jp    z,ia_rc5    ; NO ROOM, flush this frame
  544.  
  545. ; if got a buffer, insert this character.
  546. ; after doing initial buffer setup.
  547.  
  548. ia_rc6:
  549.     ld    (RX_head),hl    ; save chain head address (1st buffer)
  550.     ld    (RX_buf),hl    ; tuck away addr of our current buffer
  551.     ld    a,TRUE
  552.     ld    (RX_Allocated_Buffer),a    ; and mark that
  553.                         ; we are receiving
  554.  
  555.     ld    a,0        ; Channel 0
  556.     call    putchar        ; SLIP' frame "type" field here (Always 0)
  557.  
  558. ia_rc7:
  559.     in    a,(A_dat)    ; grab the pending character
  560.     ld    hl,(RX_buf)    ; load up address of our current RX buffer
  561.     call    putchar        ; and stuff in this particular buffer
  562.     jp    c,ia_rc2    ; If NO ROOM, flush this frame.
  563.     ld    (RX_buf),hl    ; HL might have changed in putchar()
  564.  
  565. ia_rc9:
  566.     pop    hl
  567.     pop    af
  568.  
  569.     ei
  570.     reti                ; nothing else to do here
  571.  
  572.  
  573. ; if no room, flush this frame (sigh)
  574. ia_rc2:
  575.     xor    a
  576.     ld    (RX_Allocated_Buffer),a
  577.     ld    hl,(RX_head)
  578.     call    free_chain
  579. ia_rc5:
  580.     ld    a,TRUE
  581.     ld    (RX_flushing),a    ; we are in the midst of
  582.                     ; flushing this frame
  583.     call    STA_on            ;ddd Note that we are in flushing
  584.                     ;state
  585.     jp    ia_rc9
  586.  
  587. ;---------------------------------------------------------------------------
  588. ; From out point of view, this interrupt is only interesting because it
  589. ; tells us if we're at end of frame.
  590. ia_special:
  591.     push    af
  592.     push    hl        ; regs we'll need
  593.  
  594.     ld    a,1
  595.     out    (A_ctl),a    ; ready to read RR1
  596.     in    a,(A_ctl)    ; OK, grab RR1
  597.  
  598. ; First check if RX overrun.  This is VERY BAD, so what can we do?
  599. ; Well, we merely treat it as a bad CRC, that is, just flushing the
  600. ; frame.  I don't like dropping chars (and it shouldn;t happen very often)
  601. ; but at high speeds, it may occur with 2.5 MHz z80s.
  602.  
  603.     bit    5,a        ; RX overrun?
  604.     jp    nz,ia_sp8    ; If a problem, treat as bad CRC
  605.                 ; That is, flush this frame....
  606. ;ia_sp0:
  607.     bit    7,a        ; check state of End of Frame bit
  608.     jp    z,ia_sp8    ; Else something weird happened - probably
  609.                 ; RX overrun. In any case, flush this frame.
  610.                 ; error reset & then exit
  611.                 ; that is, treat like it was a CRC error
  612.  
  613. ; If End of Frame, check CRC bit for valid.
  614. ia_sp1:
  615.     bit    6,a        ; Check CRC error bit
  616.     jp    nz,ia_sp8    ; If CRC error bit is on, then was CRC error
  617.  
  618. ; First ensure that we indeed have a buffer allocated...
  619.     ld    a,(RX_Allocated_Buffer)
  620.     or    a
  621.     jp    z,ia_sp9    ; if no buffer allocated, ignore this.
  622.  
  623. ; Else this was a good frame, and we should ship it out to host
  624. ; Leave the first CRC character at end of buffer chain in the buffer, as
  625. ; getchar() will flush it.
  626.  
  627.     ld    hl,(RX_head)
  628.     call    out_queue_insert    ; Shove this buffer string onto
  629.                     ; output queue
  630.     xor    a
  631.     ld    (RX_Allocated_Buffer),a    ; We don't have a buffer
  632.                         ; allocated for the next
  633.                         ; frame...
  634.     jp    ia_sp9
  635.  
  636. ; get here if there was a bad CRC
  637. ia_sp8:
  638.     ld    a,(RX_Allocated_Buffer)    ; If we don't have any
  639.                         ; buffers allocated, then
  640.     or    a        ;8 Feb - SET CONDITION CODES !!!!!!
  641.     jp    z,ia_sp9    ; we MUST NOT "release" them !!! 10 Sep 86
  642.                 ; if they are not allocated !!!
  643.     xor    a
  644.     ld    (RX_Allocated_Buffer),a
  645.                 ; not receiving if we have bad CRC
  646.     ld    hl,(RX_head)
  647.     call    free_chain    ; free up all buffer(s)
  648.  
  649. ia_sp9:
  650.     ld    a,30h        ; error reset
  651.     out    (A_ctl),a
  652.     in    a,(A_dat)    ; Avoid spurious RCA interrupt
  653.  
  654.     ld    a,03h        ; [JS] select WR3
  655.     out    (A_ctl),a    ; [JS]
  656.     ld    a,0D9h        ; [JS] enter hunt mode
  657.     out    (A_ctl),a    ; [JS]
  658.     xor    a
  659.     ld    (RX_State),a    ; [JS] store sync/hunt state
  660.     ld    (RX_flushing),a
  661.  
  662.     ifdef    HARDWARE
  663. ; Software DCD filetr
  664.     ld    a,(Full_Duplex)
  665.     or    a
  666.     jp    nz,ia_spsd
  667.  
  668.     ld    a,(TX_State)
  669.     cp    2
  670.     jp    nc,ia_spsd
  671.  
  672.     ld    a,(Soft_DCD)
  673.     bit    1,a
  674.     jp    z,ia_spsd
  675.  
  676.     ld    a,1
  677.     ld    (TX_State),a
  678.     ld    a,(SlotTime)
  679.     ld    (TX_Timer),a
  680. ia_spsd:
  681.  
  682.     endif
  683.  
  684.     pop    hl
  685.     pop    af
  686.  
  687.     ei
  688.     reti
  689.  
  690. ;---------------------------------------------------------------------------
  691. ; for ext/status interrupts on Modem, get DCD state into memory, and
  692. ; deallocate any spurious buffers (buffer stuff done 30 Sep 86).
  693. ia_ext:
  694.     push    af
  695.     ld    a,10h        ; reset ext/status interrupts
  696.     out    (A_ctl),a
  697.     in    a,(A_ctl)    ; grab RR0
  698.     ld    (A_RR0),a
  699.     bit     4,a             ; [JS] check sync/hunt bit
  700.     jp      nz,ia_ex1    ; [JS] no need to worry, if not zero
  701.     ld      a,(RX_State)    ; [JS] it is 0! Did it change?
  702.     or      a               ; [JS]
  703.     jp      nz,ia_ex9    ; [JS] no, this is a DCD,CTS or EOM-interrupt
  704.     ld    a,TRUE        ; [JS] indeed, it changed!
  705.     ld      (RX_State),a    ; [JS] next time, we'll know
  706.  
  707.     ld    a,(RX_Allocated_Buffer)    ; if we are not in the
  708.                         ; receiving state...
  709.     or    a        ; then there are no allocated buffers and...
  710.     jp    z,ia_ex9    ; we MUST NOT "release" them !!! 10 Sep 86
  711.                 ; if no buffers allocated !!!
  712.     xor    a
  713.     ld    (RX_Allocated_Buffer),a    ; not receiving
  714.     push    hl
  715.     ld    hl,(RX_head)
  716.     call    free_chain            ; free up all buffer(s)
  717.     pop    hl
  718.     jp    ia_ex9
  719. ia_ex1:
  720.     xor    a        ; [JS] Prepare for next frame start
  721.     ld    (RX_State),a    ; [JS]
  722.     ld    (RX_flushing),a
  723. ia_ex9:
  724.     pop     af
  725.     ei
  726.     reti
  727.  
  728.  
  729. ;    include    IB.MAC            ;TTY interrupt catchers
  730.  
  731. ;---------------------------------------------------------------------------
  732. ; we get here whenever -cts, -dcd or -sync inputs change, as well as break
  733. ; detection. Since -dcd
  734. ; is always tied to +5 volts, we need only worry about -cts and -sync.
  735. ; -cts is wired to pin 20, DTR, of the RS232 connector, and is supposed to
  736. ; be used for host to TNC handshaking; we ignore this transition (We assume
  737. ; that the host is always ready).  We also ignore break detection.  We are
  738. ; only interested in -sync transitions, so we can keep time.
  739. ; NOTE!  This is the ONLY routine that is allowed to use the other reg set!!
  740. ; deal with break detection...
  741.  
  742. sync_hunt    equ    10h
  743. ib_ext:
  744.     ex    af,af'
  745.     exx            ; we want the other registers
  746.     ld    a,10h
  747.     out    (B_ctl),a    ; reset ext/status interrupts
  748.     in    a,(B_ctl)    ; grab RR0
  749.     ld    d,a        ; Hold it for a moment...
  750.     and    sync_hunt    ; isolate this bit
  751.     jp    z,ib_s0
  752. ;else sync/hunt is a 1
  753.     ld    a,c
  754.     or    a
  755.     jp    z,ib_s1    ; go here if state of sync/hunt changed
  756.  
  757.  
  758. ; Here if sync/hunt bit did NOT change - maybe something else did....
  759. ib_s9:
  760.     ld    a,d        ; retreive RRO from above
  761.     and    Break_Abort    ; Check if we are doing a break/abort thing
  762.     jp    z,ib_NBA    ; There if No break/abort
  763.  
  764. ; Else Break/Abort bit on, note state change...
  765.     ld    a,TRUE
  766.     ld    (in_break),a    ; save in mem  (probably can use E reg...)
  767.     in    a,(B_dat)    ; clear out any null character from buffer
  768.     jp    ib_BOK    ; Break OK for now...
  769.  
  770. ib_NBA:    ;if no break/abort, check if we are in break/abort state.
  771.     ld    a,(in_break)
  772.     or    a
  773.     jp    z,ib_BOK    ; Nothing going on, Break OK
  774.  
  775. ; Else we were in break mode, and this is the tail end of a break.
  776.     xor    a
  777.     ld    (in_break),a
  778.     in    a,(B_dat)    ; discard the single extraneous null
  779. ib_BOK:
  780. ib_s99:
  781.     ex    af,af'
  782.     exx
  783.     ei
  784.     reti            ; else something else & we don't care
  785. ib_s0:            ; sync/hunt is a 0
  786.     ld    a,c
  787.     or    a
  788.     jp    nz,ib_s1a    ; go here if sync/hunt changed
  789.     jp    ib_s9    ; else not interested, forget it
  790.  
  791. ;get here if state of sync/hunt changed
  792. ib_s1:
  793.     ld    c,1
  794.     jp    ib_s1b
  795. ib_s1a:                ; first fix up C for next tick
  796.     ld    c,0
  797. ib_s1b:
  798. ; Here when we've seen a real "clock tick" & dealt with C reg
  799.     inc    b
  800.     ld    a,b
  801.     cp    12
  802.     jp    nz,ib_s99        ; we act on every 12th clock tick...
  803.     ld    b,0            ; so reload divisor. This give us an
  804.                     ; effective interrupt rate of 100 Hz
  805.  
  806. ; Decrement all the timers
  807.  
  808.     ld    a,(TX_Timer)        ; Get value, and ...
  809.     or    a
  810.     jp    z,ib_s1c
  811.     dec    a            ; ... decrement it as required.
  812.     ld    (TX_Timer),a
  813. ib_s1c:
  814.     jp    ib_s99
  815.  
  816.  
  817. ;---------------------------------------------------------------------------
  818. ib_special:
  819.     push    af
  820. ib_sp9:            ; Normal exit
  821.     ld    a,30h        ; error reset
  822.     out    (B_ctl),a
  823.     pop    af
  824.     ei
  825.     reti
  826.  
  827. ;---------------------------------------------------------------------------
  828. ; The TX has become empty, shove a new character out
  829. ib_tbe:
  830.     push    af        ; new char will return in A
  831.     push    hl
  832.  
  833.     ld    a,(Out_esc_mode)
  834.     or    a
  835.     jp    z,ib_t1    ; not escaped, so go here
  836. ; else we are escaped, so send escaped char
  837.     ld    a,(Out_char)    ; char which follows escape
  838.     or    a
  839.     jp    z,ib_t2    ; special case if at end of frame, clean up
  840.     out    (B_dat),a
  841.     xor    a
  842.     ld    (Out_esc_mode),a    ; get out of escaped mode
  843.     jp    ib_t9        ; all for now...
  844. ib_t1:
  845.     ld    hl,(out_chain_head)    ; we are currently on this buffer,
  846.     call    getchar            ; as getchar() needs to know
  847.     ld    (out_chain_head),hl    ; maybe HL changed,so save it in case
  848.  
  849.     jp    z,ib_tdone    ; if no more chars, deal with this
  850.     cp    FESC
  851.     jp    z,ib_t1a    ; deal with FESC char in data stream
  852.     cp    FEND
  853.     jp    z,ib_t1b    ; deal with FEND char in data stream
  854. ; else this char is nothing special, so shove it out
  855.  
  856.     out    (B_dat),a    ; shove it out
  857.     jp    ib_t9    ; if this is not last char, all for now
  858.  
  859. ; else this is last char, send FEND
  860. ib_tdone:
  861.     ld    a,FEND
  862.     out    (B_dat),a
  863.     ld    a,TRUE
  864.     ld    (Out_esc_mode),a    ; set special escaped mode by...
  865.     xor    a
  866.     ld    (Out_char),a        ;... making escaped char a 0
  867.     jp    ib_t9        ; all till TX Buffer goes empty again.
  868.  
  869. ; here if are completely done sending frame
  870. ib_t2:
  871.     push    de        ; need this for a moment
  872.     ld    hl,(out_head_cbuf)
  873.     inc    hl
  874.     inc    hl        
  875.     ld    de,out_bottom
  876.     or    a
  877.     push    hl
  878.     sbc    hl,de
  879.     pop    hl            ; this may be the one we want
  880.     pop    de
  881.     jp    nz,ib_t2a        ; yes it is!
  882.  
  883.     ld    hl,Out_Top        ; else, make a circular buffer
  884. ib_t2a:
  885.     ld    (out_head_cbuf),hl    ; we will work on this one next
  886.     xor    a
  887.     ld    (out_started),a        ; not doing outputs anymore
  888.     ld    (Out_esc_mode),a    ; !! NOT IN ESCAPED MODE ANYMORE !!
  889.  
  890.     ld    a,28h            ; NEEDED for ASYNC
  891.     out    (B_ctl),a        ; reset TX interrupt pending
  892.  
  893. ib_t9:
  894.     pop    hl
  895.     pop    af
  896.     ei
  897.     reti                ; now get our butts out of here...
  898.  
  899. ; here is FESC in data stream
  900. ib_t1a:
  901.     out    (B_dat),a        ; Ship FESC character to port
  902.     ld    a,TFESC            ; ready what will be next char
  903. ib_t1z:
  904.     ld    (Out_char),a        ; set char for next time
  905.     ld    a,TRUE
  906.     ld    (Out_esc_mode),a    ; we are in escaped mode
  907.     jp    ib_t9        ; all for now
  908.  
  909. ; here is FEND in data stream
  910. ib_t1b:
  911.     ld    a,FESC
  912.     out    (B_dat),a
  913.     ld    a,TFEND
  914.     jp    ib_t1z        ; rest is same as FESC case
  915.  
  916.  
  917. ;---------------------------------------------------------------------------
  918. ; Got a char from the TTY port, deal with it.
  919.  
  920. ib_rca:
  921.     push    af
  922.  
  923.     in    a,(B_ctl)    ; Read RR0; force reg pointer to be 0
  924.     ld    a,1
  925.     out    (B_ctl),a    ; ready to read RR1
  926.     in    a,(B_ctl)    ; Grab RR1
  927.     and    Framing_Error    ; Isolate the FE bit
  928.     jp    z,ib_Rtop    ; No Framing Error, so process this char
  929.  
  930. ; Else we have a Framing Error - Ignore this char & flush this frame...
  931.     call    STA_off        ; Off with the LED!
  932.     in    a,(B_dat)    ; Flush erroneous character
  933.     xor    a
  934.     ld    (In_state),a    ; Force receiver to look for FEND
  935.     ld    a,(In_Allocated_Buffer)
  936.     or    a
  937.     jp    z,ib_rc9    ; If no buffer is allocated, done; Exit.
  938.  
  939. ; Else we were receiving a data SLIP frame, so flush it.
  940.     push    hl
  941.     ld    hl,(In_head)
  942.     call    free_chain    ; Dump these buffers back to free list
  943.     pop    hl
  944.     jp    ib_rc9    ; And get out of here!
  945.  
  946. ib_rTop:
  947.     ld    a,(In_state)    ; get our state machine value
  948.     or    a
  949.     jp    z,ib_r0    ; in state 0, waiting for FEND
  950.     cp    1
  951.     jp    z,ib_r1    ; in state 1, saw FEND
  952.     cp    2
  953.     jp    z,ib_r2    ; in state 2, data to follow
  954.     cp    3
  955.     jp    z,ib_r3    ; saw FESC, expecting TFESC or TFEND
  956.     cp    10
  957.     jp    z,ib_r10    ; Expecting TXdelay
  958.     cp    20
  959.     jp    z,ib_r20    ; Expecting P value
  960.     cp    30
  961.     jp    z,ib_r30    ; Expecting SlotTime value
  962.     cp    40
  963.     jp    z,ib_r40    ; Expecting TailTime value
  964.     cp    50
  965.     jp    z,ib_r50    ; Expecting Full/Half duplex value
  966.  
  967.     ifdef    HARDWARE
  968.  
  969.     cp    60
  970.     jp    z,ib_r60    ;[JDZ] Expecting Set Hardware value
  971.  
  972.     ifndef    TASCO
  973.     cp    61
  974.     jp    z,ib_r61    ;[JDZ] Expecting Set Hardware value
  975.     endif
  976.  
  977.     endif
  978. ;else we don't know what happened, ignore it.
  979. ib_rcjunk:
  980.     in    a,(B_dat)
  981. ib_rcFEND:
  982.     xor    a
  983. ib_rcSTATE:
  984.     ld    (In_State),a    ;go into In_State 0, FEND hunt
  985. ib_rc9:
  986.     pop    af        ; throw it away, we don't need junk
  987.     ei
  988.     reti
  989.  
  990. ; Here if we are hunting for FEND character
  991. ib_r0:
  992.     call    STA_off
  993.  
  994.     in    a,(B_dat)
  995.     cp    FEND
  996.     jp    nz,ib_rc9    ; if we didn't see an FEND, keep looking
  997.  
  998. ; else is an FEND, change state
  999.     ld    a,1
  1000.     jp    ib_rcSTATE
  1001.  
  1002. ; Get here if we've seen FEND character; look for command byte
  1003. ib_r1:
  1004.     call    STA_off
  1005.     in    a,(B_dat)
  1006.     cp    FEND
  1007.     jp    z,ib_rc9    ; Just another FEND, keep looking for cmd
  1008.  
  1009.     call    STA_on        ;getting valid SLIP; show in STA LED
  1010.  
  1011. ; Here if we DO NOT have an FEND (expecting command byte)
  1012.     ifndef    ALONE
  1013.         cp    0ffh
  1014.         jp    z,kiss_exit
  1015.     endif
  1016.  
  1017.     and    0fh
  1018.     jp    z,ib_r1a    ; 0 command means data will follow
  1019.     cp    1
  1020.     jp    z,ib_r1b    ; 1 command means TXdelay will follow
  1021.     cp    2
  1022.     jp    z,ib_r1c    ; 2 command means P(Persistence) will follow
  1023.     cp    3
  1024.     jp    z,ib_r1d    ; 3 command means Slot Time will follow
  1025.     cp    4
  1026.     jp    z,ib_r1e    ; 4 command means TailTime to follow
  1027.     cp    5
  1028.     jp    z,ib_r1f    ; 5 command means Full/Half duplex to come
  1029.  
  1030.     ifdef    HARDWARE
  1031.  
  1032.     cp    6
  1033.     jp    z,ib_r1g    ; 6 command means Set Hardware to come
  1034.  
  1035.     endif
  1036.  
  1037. ; Here if we receive bogus command byte, flush rest of frame
  1038.  
  1039.     call    STA_off        ;bogosity, so turn off STA LED
  1040.  
  1041.     jp    ib_rcFEND
  1042.  
  1043. ; exit kiss mode.
  1044.     ifndef    ALONE
  1045. kiss_exit:
  1046.         ld    hl,(000eh)
  1047.         res    4,(hl)
  1048.         ld    hl,0000h
  1049.         push    hl
  1050.         ld    hl,(0019h)
  1051.         jp    (hl)
  1052.     endif
  1053.  
  1054. ; Data are expected, change state
  1055. ib_r1a:
  1056.     ld    a,2
  1057.     jp    ib_rcSTATE
  1058.  
  1059. ; TXdelay to follow, change state
  1060. ib_r1b:
  1061.     ld    a,10
  1062.     jp    ib_rcSTATE
  1063.  
  1064. ; P to follow, change state
  1065. ib_r1c:
  1066.     ld    a,20
  1067.     jp    ib_rcSTATE
  1068.  
  1069. ; SlotTime to follow, change state
  1070. ib_r1d:
  1071.     ld    a,30
  1072.     jp    ib_rcSTATE
  1073.  
  1074. ; TailTime to follow, change state
  1075. ib_r1e:
  1076.     ld    a,40
  1077.     jp    ib_rcSTATE
  1078.  
  1079. ; Full/Half Duplex to follow, change state
  1080. ib_r1f:
  1081.     ld    a,50
  1082.     jp    ib_rcSTATE
  1083.  
  1084.     ifdef    HARDWARE
  1085. ; Set Hardware to follow, change state
  1086. ib_r1g:
  1087.     ld    a,60
  1088.     jp    ib_rcSTATE
  1089.     endif
  1090.  
  1091. ; These bytes are data
  1092. ib_r2:
  1093.     in    a,(B_dat)
  1094.     cp    FEND
  1095.     jp    z,ib_r2b    ; FEND means to queue this buffer
  1096.     push    af        ; Save the char we read on stack for a bit..
  1097.  
  1098.     ld    a,(In_Allocated_Buffer)
  1099.     or    a
  1100.     jp    nz,ib_r2c    ; if we already allocated buffer
  1101.  
  1102.     push    hl
  1103.     call    allocate_buffer    ; get our initial buffer to mess with
  1104.     jp    nz,ib_r22
  1105.  
  1106. ; else no room, flush this frame
  1107.     pop    af
  1108.     pop    hl        ; keep stack tidy
  1109.     jp    ib_rcFEND
  1110.  
  1111. ib_r22:
  1112.     ld    a,TRUE
  1113.     ld    (In_Allocated_Buffer),a    ; make ourselves active
  1114.  
  1115.     ld    (In_buffer),hl
  1116.     ld    (In_head),hl    ; save current & head of chain pointers
  1117.     pop    hl
  1118.  
  1119. ib_r2c:
  1120.     pop    af        ; Retreive the data char we just got...
  1121.     cp    FESC
  1122.     jp    z,ib_r2a    ; If FESC in data stream, switch state
  1123.  
  1124.     push    hl
  1125.     ld    hl,(In_buffer)
  1126.     call    putchar        ; shove this character into our buffer
  1127.     jp    nc,ib_r2ca
  1128.  
  1129.     xor    a
  1130.     ld    (In_Allocated_buffer),a
  1131.     ld    hl,(In_head)
  1132.     call    free_buffer
  1133.     pop    hl
  1134.     jp    ib_rcFEND
  1135.  
  1136. ib_r2ca:
  1137.     ld    (In_buffer),hl    ; save in case HL changed
  1138.     pop    hl
  1139.     jp    ib_rc9    ; done so far
  1140.  
  1141.  
  1142. ; FESC character seen while grabbing data
  1143. ib_r2a:
  1144.     ld    a,3
  1145.     jp    ib_rcSTATE
  1146.  
  1147. ; FEND character seen while grabbing data
  1148. ib_r2b:
  1149.     ld    a,(In_Allocated_Buffer)
  1150.     or    a
  1151.     jp    z,ib_r2z    ; No bytes accumulated, so is null frame
  1152.  
  1153. ; else we must ship this frame to TX
  1154.     push    hl        ; This bug found 29 Sep (must save HL !!!)
  1155.     ld    hl,(In_Buffer)
  1156.     call    putchar        ; put a garbage character at the end of
  1157.                 ; last buffer because getchar() will strip
  1158.                 ; it. Hack needed because of RX use of
  1159.                 ; putchar/getchar.
  1160.     ld    hl,(In_head)
  1161.     jp    nc,ib_r2za
  1162.     call    free_chain
  1163.     jp    ib_r2zb
  1164. ib_r2za:
  1165.     call    TX_queue_insert
  1166. ib_r2zb:
  1167.     pop    hl
  1168.     xor    a
  1169.     ld    (In_Allocated_Buffer),a    ; input no longer active
  1170. ib_r2z:                ; entry point for null frame
  1171.     call    STA_off        ;done getting this frame, turn STA LED off
  1172.     ld    a,1        ; Keep as was, FENDs only at end in v.32
  1173.  
  1174.     jp    ib_rcSTATE
  1175.  
  1176.  
  1177.  
  1178. ; here if we've seen FESC in data stream
  1179. ib_r3:
  1180.     in    a,(B_dat)
  1181.     cp    TFESC
  1182.     jp    z,ib_r3a
  1183.     cp    TFEND
  1184.     jp    z,ib_r3b
  1185.  
  1186. ; Else we don't know what the hell it is, so ignore & keep collecting bytes
  1187.     ld    a,2
  1188.     jp    ib_rcSTATE
  1189.  
  1190. ; here if we've seen TFESC after an FESC in data stream; write an FESC
  1191. ib_r3a:
  1192.     ld    a,FESC
  1193. ib_r3z:
  1194.     push    hl
  1195.     ld    hl,(In_buffer)
  1196.     call    putchar
  1197.     jp    nc,ib_r3za
  1198.  
  1199.     xor    a
  1200.     ld    (In_Allocated_buffer),a
  1201.     ld    hl,(In_head)
  1202.     call    free_buffer
  1203.     pop    hl
  1204.     jp    ib_rcFEND
  1205.  
  1206. ib_r3za:
  1207.     ld    (In_buffer),hl
  1208.     pop    hl
  1209.     ld    a,2
  1210.     jp    ib_rcSTATE
  1211.  
  1212. ; Here if we've seen TFEND after FESC in data stream; write FEND
  1213. ib_r3b:
  1214.     ld    a,FEND
  1215.     jp    ib_r3z        ; rest is same as for TFESC case
  1216.  
  1217. ; This character is interpreted as TXdelay
  1218. ib_r10:
  1219.     in    a,(B_dat)
  1220.     ld    (TXdelay),a
  1221.     jp    ib_rcFEND
  1222.  
  1223. ; This charcter is P, Persistence value
  1224. ib_r20:
  1225.     in    a,(B_dat)
  1226.     ld    (Persistence),a
  1227.     jp    ib_rcFEND
  1228.  
  1229. ; This character is SlotTime value
  1230. ib_r30:
  1231.     in    a,(B_dat)
  1232.     ld    (SlotTime),a
  1233.     jp    ib_rcFEND
  1234.  
  1235.  
  1236. ; This character is TailTime value
  1237. ib_r40:
  1238.     in    a,(B_dat)
  1239.     ld    (TailTime),a
  1240.     jp    ib_rcFEND
  1241.  
  1242.  
  1243. ; This character is Full/Half Duplex value
  1244. ; 0 means Half Duplex, non-zero means Full Duplex
  1245. ib_r50:
  1246.     in    a,(B_dat)
  1247.     ld    (Full_Duplex),a
  1248.     jp    ib_rcFEND
  1249.  
  1250.     ifdef    HARDWARE
  1251. ; This character is Set Hardware value
  1252. ; data means Output Address.
  1253. ib_r60:
  1254.     in    a,(B_dat)
  1255.     cp    0feh        ; CTS flow off
  1256.     jp    nc,ib_r60cts
  1257.     cp    0fch        ; Reserved
  1258.     jp    nc,ib_rcFEND
  1259.     cp    0f8h        ; DCD
  1260.     jp    nc,ib_r60DCD
  1261.  
  1262.     ifndef    TASCO
  1263.     cp    020h
  1264.     jp    nc,ib_rcFEND
  1265.     add    a,0a0h        ; A5=1 OUT_DATA address, Ch A
  1266.     ld    (Out_Address),a
  1267.     ld    a,61
  1268.     jp    ib_rcSTATE
  1269.     else
  1270.     jp    ib_rcFEND
  1271.     endif
  1272.  
  1273. ;    CTS flow
  1274. ib_r60cts:
  1275.     sub    0feh
  1276.     ld    (CTS_Control),a
  1277.     jp    ib_rcFEND
  1278.  
  1279. ;    Software DCD
  1280. ib_r60dcd
  1281.     sub    0f8h
  1282.     ld    (Soft_DCD),a
  1283.     jp    ib_rcFEND
  1284.  
  1285.     ifndef    TASCO
  1286. ; data means Output Data.
  1287. ib_r61:
  1288.     push    bc
  1289.     ld    a,(Out_Address)
  1290.     ld    c,a
  1291.     in    a,(B_dat)
  1292.     out    (c),a
  1293.     pop    bc
  1294.     jp    ib_rcFEND
  1295.     endif
  1296.  
  1297.     endif
  1298.  
  1299. ;    include    BUFFERS.MAC        ;all buffer-related stuff in here
  1300.                     ;plus all (eventually) variables
  1301. ;
  1302. ; The buffer list is kept from "bottom" to the end of RAM.  The format of the
  1303. ; buffers is:
  1304. ;+------+--------+-------+---------------------------------------------------+
  1305. ;| next | Nbytes | Nread | data                             |
  1306. ;+------+--------+-------+---------------------------------------------------+
  1307. ;
  1308. ; 2 bytes 1 byte   1 byte  124 bytes  (Total 128 bytes)
  1309. ; next     Pointer to next buffer on this buffer chain (or 0 if no more)
  1310. ; Nbytes Number of bytes in this buffer that are valid
  1311. ; Nread  Number of bytes read from this buffer (used by getchar)
  1312. ; data   124 bytes of data (not all is necessarily valid, see Nbytes field)
  1313. ;
  1314. ; The buffer pool is all here, and as processes need buffer space, it is all
  1315. ; allocated out of this pool.  See allocate_buffer and free_buffer code.
  1316.  
  1317.  
  1318. ;---------------------------------------------------------------------------
  1319. ; return in HL a pointer to a free buffer.  If there are not more buffers,
  1320. ; return with Z flag set.
  1321. ; destroys no registers except return value HL.
  1322. ; IS CALLED FROM AN INTERRUPT ROUTINE, so this operation is atomic.
  1323.  
  1324. allocate_buffer:
  1325.  
  1326.     push    bc
  1327.     push    af
  1328.  
  1329.     ld    hl,(free)        ;get pointer to head of free list
  1330.     ld    a,h
  1331.     or    l
  1332.     jp    nz,OK_allocate_buffer    ; assure we're not off the end
  1333.  
  1334. ;get here if no more buffers.  Return Z set - do not disturb A.
  1335.     pop    af
  1336.     ld    b,a            ; tuck A away for a moment...
  1337.     xor    a            ; turn on Z bit
  1338.     ld    a,b            ; retreive original A
  1339.     pop    bc
  1340.     ret
  1341.  
  1342. OK_allocate_buffer:
  1343.  
  1344.     xor    a
  1345.     ld    c,(hl)            ;grab lo byte of next free buffer
  1346.     ld    (hl),a            ; clear it out
  1347.     inc    hl
  1348.     ld    b,(hl)            ; "ld bc,(hl)" now hi byte
  1349.     ld    (hl),a            ; clear it out, too
  1350.     ld    (free),bc        ; update with new free list pointer
  1351.  
  1352.     dec    hl            ; Now HL is at head of new buffer
  1353.  
  1354.     pop    af
  1355.     ld    b,a            ; tuck A away for a moment...
  1356.     ld    a,1
  1357.     or    a            ; Turn Z bit off (i.e., all OK)
  1358.     ld    a,b            ; retreive original A
  1359.  
  1360.     pop    bc
  1361.     ret
  1362.  
  1363. ;---------------------------------------------------------------------------
  1364. ; free_buffer gets passed a pointer (in HL) to a buffer to be freed.  The
  1365. ; buffer is placed on the head of the free list.  The nbytes & nread fields
  1366. ; are made 0 before placing on free list.
  1367. ; THIS ROUTINE IS CALLED AT INTERRUPT LEVEL, so results are atomic.
  1368. ; no registers are disturbed at all.  The FREE pointer is updated, however.
  1369. ; 159 T states [ 63.6 usec @ 2.5 MHz ]
  1370.  
  1371. free_buffer:
  1372.     push    af
  1373.     push    bc        ;we'll use these
  1374.     push    hl        ;this will be new head of free list
  1375.  
  1376.     ld    bc,(free)    ;get old free head
  1377.     ld    (hl),c        ;put on free chain, first low byte...
  1378.     inc    hl
  1379.     ld    (hl),b        ; ...now hi byte
  1380.     xor    a
  1381.     inc    hl
  1382.     ld    (hl),a        ; zero out nbytes field
  1383.     inc    hl
  1384.     ld    (hl),a        ; and the nread field of new head of free
  1385.  
  1386.     pop    hl        ;get new head of free list back
  1387.     ld    (free),hl    ;and save it in memory where it belongs
  1388.  
  1389.     pop    bc
  1390.     pop    af
  1391.     ret
  1392. ; --------------------------------------------------------------------------
  1393. ; putchar - HL contains pointer to buffer, A contains the character to put
  1394. ; into the buffer.  Upon return, char is put into this buffer if ther is
  1395. ; room, else another buffer is allocated and HL is updated to point to this
  1396. ; new buffer.  The new buffer is chained onto the old buffer in this case.
  1397. ; The calling routine is responsible for maintaing both the head of a
  1398. ; particular buffer chain (if it needs it), and the current buffer being
  1399. ; manipulated. THIS ROUTINE IS CALLED AT INTERRUPT LEVEL, so is atomic.  No
  1400. ; registers disturbed, except that HL may have a new value.
  1401. ; 211 T states [  84.4 usec @ 2.5 MHz ]    no new buffer required
  1402. ; 338 T states [ 135.2 usec @ 2.5 MHz ]    New buffer needed
  1403.  
  1404. ; [JDZ] If carry flag is on, then memory is not enough to putchar.
  1405.  
  1406. putchar:
  1407.     push    bc
  1408.     push    ix
  1409.     push    af
  1410.     push    hl        ;do it this way for a reason...
  1411.  
  1412.     pop    ix        ;get buffer pointer into IX
  1413.     ld    a,(ix+2)    ;grab nbytes field
  1414.     cp    124        ;max of 124 chars in a buffer
  1415.     jp    nz,putc1
  1416.     call    putc_need_new_buffer
  1417. ; if it takes this call, it returns with a new buffer, with HL pointing to
  1418. ; it (as well as IX), and with A reg set to 0.
  1419. ; else just plunk into buffer
  1420.     jp    nc,putc1
  1421.     pop    af
  1422.     scf
  1423.     jp    putc2
  1424. putc1:
  1425.     inc    (ix+2)        ;one more char will go into this buffer
  1426.     ld    c,a        ;get previous nbytes
  1427.     xor    a
  1428.     ld    b,a        ; bc <- nbytes, filled out to 16 bits
  1429.     add    ix,bc        ; update ix to point to where char goes
  1430.     pop    af        ; retreive the char we want to save
  1431.     ld    (ix+4),a    ; save it in this buffer
  1432.     or    a        ; reset Cy flag.
  1433. putc2:
  1434.     pop    ix
  1435.     pop    bc
  1436.     ret            ;done for the moment
  1437.  
  1438. ; 127 T states [ 50.8 usec @ 2.5 MHz ] (really part of prev routine)
  1439. putc_need_new_buffer:        ;prev buffer filled, get a new one
  1440.     push    de        ; working registers
  1441.     push    hl        ; save current buffer pointer
  1442.     call    allocate_buffer    ; grab a new buffer, addr is in HL
  1443.     jp    nz,putcnb1
  1444.     pop    hl
  1445.     scf
  1446.     jp    putcnb2
  1447. putcnb1:
  1448.     ex    de,hl        ; "ld de,hl" - get new addr into DE for now
  1449.     pop    hl
  1450.     ld    (hl),e        ; link new buffer onto chain, lo byte first
  1451.     inc    hl
  1452.     ld    (hl),d        ; now hi byte, chaining done
  1453.  
  1454.     ex    de,hl        ; update HL for orig. calling routine's use
  1455.     push    hl
  1456.     pop    ix        ; upper routine needs ix pointing to new buf
  1457.     xor    a        ; and A is nbytes in calling routine, make..
  1458.                 ; zero for a new buffer
  1459. putcnb2:
  1460.     pop    de        ; done with this working register
  1461.     ret            ; all done here, let calling routine finish
  1462.  
  1463. ; --------------------------------------------------------------------------
  1464. ; getchar - grab a character from the buffer pointed at by HL, return in A.
  1465. ; if the "nread" field of this buf = "nbytes" then this buffer is exhausted,
  1466. ; so follow the chain on to the next buffer & release old buffer.  If the
  1467. ; next chain is 0, or if the nbytes field is >= nread field, then there are
  1468. ; no more bytes.  In this case, return with Z bit set; normally return with
  1469. ; Z bit reset (That is, non-zero) indicating a valid char is in A.  Note
  1470. ; that if we need to follow the chain to a new buffer, HL will be updated,
  1471. ; too, so that the calling routine needs to deal with this.
  1472. ;         no registers changed except AF and possibly HL.
  1473. ; CALLED AT INTERRUPT LEVEL, so operation is atomic.
  1474. ; 212 T states [  84.8 usec @ 2.5 MHz ]    No new buffer needed
  1475. ; 493 T states [ 197.2 usec @ 2.5 MHz ]    if following chain
  1476.  
  1477. getchar:
  1478.     push    ix        ; save because is working reg
  1479.     push    bc        ; working regs here
  1480.  
  1481.     push    hl
  1482.     pop    ix        ; ix points to this buffer
  1483.  
  1484.     ld    a,(ix+3)    ; grab Nread
  1485.     cp    (ix+2)        ; compare with Nbytes
  1486.     call    z,getc_new_buf    ; if they are same, this buffer is spent
  1487.  
  1488.     inc    (ix+3)        ; we are reading one more char, update Nread
  1489.     inc    a
  1490.     cp    (ix+2)
  1491.     jp    nz,getc_pluck_character    ; if not looking at last character
  1492.  
  1493. ; else, is the "next" pointer 0?
  1494.     push    hl
  1495.     ld    b,a        ; !!!!! SAVE  A   REG  !!!!!!! 4 Jan 87
  1496.     ld    a,(hl)
  1497.     inc    hl
  1498.     or    (hl)
  1499.     ld    a,b        ; !!!! Restore A Reg  (Gasp!)
  1500.     pop    hl
  1501.     jp    nz,getc_pluck_character
  1502.  
  1503. ; else next is 0 and we are on last char - flush it & quit
  1504.     call    free_buffer
  1505.     pop    bc
  1506.     pop    ix
  1507.     ret            ; note that Z bit is set (from above)
  1508.  
  1509. ; else we can just pluck a character out of this buffer
  1510. getc_pluck_character:
  1511.     dec    a        ; fix A from above mucking around...
  1512.  
  1513.     ld    c,a        ; get old Nread into BC
  1514.     ld    b,0        ; ditto
  1515.     add    ix,bc        ; fix buffer pointer
  1516.     ld    a,1
  1517.     or    a        ; make Z bit reset
  1518.     ld    a,(ix+4)    ; get the desired byte
  1519.  
  1520.     pop    bc
  1521.     pop    ix
  1522.     ret            ; all for this simple case
  1523.  
  1524. ; old buffer is spent, get new one (if any)
  1525.  
  1526. getc_new_buf:
  1527.     push    de        ; need this reg here
  1528.     ld    e,(hl)        ; get lo byte of Next pointer
  1529.     inc    hl
  1530.     ld    d,(hl)        ; hi byte of Next pointer (now all in DE)
  1531.     dec    hl        ; HL now back to point at spent buffer
  1532.     call    free_buffer    ; give the buffer back
  1533.  
  1534.     ex    de,hl        ; "ld hl,de" - follow chain
  1535.     push    hl
  1536.     pop    ix        ; init new IX (same as HL in this routine)
  1537.     xor    a        ; A holds Nread (needed above)
  1538.     pop    de        ; release DE from use by this excursion
  1539.     ret
  1540.  
  1541. ; --------------------------------------------------------------------------
  1542. ; free_chain - MUST be called from interrupt routine to guarantee
  1543. ; atomicity.  Takes buffer chain pointed at by HL and returns them to free
  1544. ; buffer list
  1545. ; 303 T states + (n_on_chain-1)*238 T states
  1546. ; [ 121.2 usec + (n_on_chain-1)*95.2 usec ]
  1547.  
  1548. free_chain:
  1549.     push    af
  1550.     push    de
  1551.     push    hl        ; we will muck with these
  1552.  
  1553. fc_0:
  1554.     ld    e,(hl)        ; get lo part of next buffer pointer
  1555.     inc    hl
  1556.     ld    d,(hl)        ; now hi part of next buffer pointer
  1557.     dec    hl
  1558.     call    free_buffer    ; release this buffer
  1559.     ld    a,d
  1560.     or    e
  1561.     jp    z,fc_9        ; if "next" address is 0, we are at end
  1562. ; else we've got more on this chain - deal with them.
  1563.     ex    de,hl        ; "ld hl,de" - HL points to "next"
  1564.     jp    fc_0
  1565.  
  1566. fc_9:
  1567.     pop    hl
  1568.     pop    de
  1569.     pop    af
  1570.     ret
  1571.  
  1572. ; --------------------------------------------------------------------------
  1573. ; out_queue_insert - Places the just-received buffer on the output queue.
  1574. ; The address of the RX buffer just received is in HL.
  1575. ; The output queue is a circular buffer.  The output routine keeps sending
  1576. ; out buffers until its out_head_cbuf pointer equals its out_tail_cbuf
  1577. ; pointer. The output routine never mucks with the out_tail_cbuf pointer;
  1578. ; similarly, this routine never changes the out_head_cbuf pointer.  So it
  1579. ; is possible to
  1580. ; insert new entries into the output circular buffer queue without
  1581. ; disturbing the entry which is being sent to the output port.
  1582.  
  1583. out_queue_insert:
  1584.     push    af
  1585.     push    de
  1586.     push    hl        ; use these
  1587.  
  1588.     ex    de,hl        ; "ld de,hl" - move buffer to link addr
  1589.     ld    hl,(out_tail_cbuf) ; Grab next free location 
  1590.     ld    (hl),e        ; set lo addr 1st
  1591.     inc    hl
  1592.     ld    (hl),d        ; now hi addr
  1593.     inc    hl        ; Now HL points to next free entry in...
  1594.     ld    de,out_bottom    ; ...circ buf, unless we're at end
  1595.     or    a        ; clear carry
  1596.     push    hl        ; (may be be needed address)
  1597.     sbc    hl,de
  1598.     pop    hl        ; get back what we think is good
  1599.     jp    nz,oqi_0
  1600.     
  1601.     ld    hl,Out_Top    ; get here if we're at end of circ buffer.
  1602. oqi_0:
  1603.     ld    (out_tail_cbuf),hl
  1604.     pop    hl
  1605.     pop    de
  1606.     pop    af        ; keep clean
  1607.     ret
  1608.  
  1609.  
  1610. ;---------------------------------------------------------------------------
  1611. ; TX_Queue_Insert - similar to Out_queue_insert, but with different queue.
  1612. ; Also, increments the byte TX_Outstanding (which counts the number of
  1613. ; frames ready to be dumped to the modem port).  This routine, like
  1614. ; out_queue_insert, does not need to worry about queue wrap-around because
  1615. ; there are more entries in each of these queues than there are buffers
  1616. ; available.  Yes, I know this is a hack, and wastes some RAM space, but it
  1617. ; means I don't have to check for overflows here.
  1618. ; The queue is circular, and sometimes I call it a "CBuf" - Circular Buffer
  1619.  
  1620. TX_Queue_Insert:
  1621.     push    af
  1622.     push    de
  1623.     push    hl
  1624.     ex    de,hl            ; "ld de,hl" - save chain head in DE
  1625.     ld    hl,(TX_Tail_CBuf)    ; Next free location in TX CBuf
  1626.     ld    (hl),e
  1627.     inc    hl
  1628.     ld    (hl),d            ; put this chain into TX Queue
  1629.     inc    hl            ; HL is next availble TX Queue ...
  1630.     ld    de,TX_Bottom        ; ... unless we are at bottom of ...
  1631.     or    a            ; ... the TX Queue
  1632.     push    hl
  1633.     sbc    hl,de
  1634.     pop    hl
  1635.     jp    nz,TQI_0        ; go there if not at buffer bottom
  1636.  
  1637.     ld    hl,TX_Top        ; else reload with top of queue val
  1638. TQI_0:
  1639.     ld    (TX_Tail_CBuf),hl    ; save next free queue slot
  1640.     ld    hl,TX_Outstanding
  1641.     inc    (hl)            ; +1 more frame outstanding now
  1642.     pop    hl
  1643.     pop    de
  1644.     pop    af
  1645.     ret
  1646.  
  1647. ;-----------------------------------------------------------------------------
  1648. ; Setup HL & TX_Chain_Head for transmission of next chain.
  1649.  
  1650. TXnext_CBuf:
  1651.     push    af
  1652.     push    de
  1653.     ld    hl,(TX_Head_CBuf)
  1654.     ld    e,(hl)
  1655.     inc    hl
  1656.     ld    d,(hl)            ; DE -> next chain to transmit
  1657.     inc    hl            ; HL MIGHT be next CBuf entry pointer
  1658.     push    de
  1659.     ld    de,TX_Bottom
  1660.     or    a            ;clear carry
  1661.     push    hl            ;save what might be correct value
  1662.     sbc    hl,de
  1663.     pop    hl
  1664.     pop    de
  1665.     jp    nz,TXn_1        ;go there if not at end of circ. buf
  1666.  
  1667.     ld    hl,TX_Top        ;else we wrap aroune
  1668. TXn_1:
  1669.     ld    (TX_Head_CBuf),hl    ;save next circ buf pointer in mem
  1670.     ex    de,hl            ;return ptr to next chain to TX in HL
  1671.     ld    (TX_Chain_Head),hl    ;TX RCA routine needs this
  1672.     pop    de
  1673.     pop    af
  1674.     ret
  1675.  
  1676.  
  1677. ;-----------------------------------------------------------------------------
  1678. STA_on:        ;Turn the STA LED on.  ASSUMES that interrupts are disabled!
  1679.     push    af
  1680.     ld    a,5
  1681.     out    (A_ctl),a        ; ready to write WR5
  1682.     ld    a,(A_WR5)        ; get memory copy
  1683.     and    NOT ALED        ; set DTR bit to 0 so LED goes on
  1684.     out    (A_ctl),a        ; Actually turn on STA LED now...
  1685.     ld    (A_WR5),a        ; update memory copy
  1686.     pop    af
  1687.     ret
  1688. ;-----------------------------------------------------------------------------
  1689. STA_off:    ;Turn the STA LED off.  ASSUMES that interrupts are disabled!
  1690.     push    af
  1691.     ld    a,5
  1692.     out    (A_ctl),a        ; ready to write WR5
  1693.     ld    a,(A_WR5)        ; get memory copy
  1694.     or    ALED            ; set DTR bit to 1 so LED goes off
  1695.     out    (A_ctl),a        ; Actually turn off STA LED now...
  1696.     ld    (A_WR5),a        ; update memory copy
  1697.     pop    af
  1698.     ret
  1699.  
  1700. ;These routines MUST be called with interrupts disabled!
  1701. ;-----------------------------------------------------------------------------
  1702. STA_flip:
  1703.     push    af
  1704.     in    a,(A_ctl)        ;assure we are talking to ch 0
  1705.     ld    a,5
  1706.     out    (A_ctl),a        ; ready to write WR5
  1707.     ld    a,(A_WR5)        ; get memory copy
  1708.     xor    ALED            ; [JDZ]
  1709.     out    (A_ctl),a        ; Actually turn off STA LED now...
  1710.     ld    (A_WR5),a        ; update memory copy
  1711.     pop    af
  1712.     ret
  1713.     
  1714. ;-----------------------------------------------------------------------------
  1715. CON_on:
  1716.     push    af
  1717.     ld    a,5
  1718.     out    (B_ctl),a
  1719.     ld    a,BLEDon
  1720.     ld    (B_WR5),a        ; save in mem for flip routine
  1721.     out    (B_ctl),a
  1722.     pop    af
  1723.     ret
  1724. ;-----------------------------------------------------------------------------
  1725. CON_off:
  1726.     push    af
  1727.     ld    a,5
  1728.     out    (B_ctl),a
  1729.     ld    a,BLEDoff
  1730.     ld    (B_WR5),a        ; save in mem for flip routine
  1731.     out    (B_ctl),a
  1732.     pop    af
  1733.     ret
  1734. ;-----------------------------------------------------------------------------
  1735. CON_flip:
  1736.     push    af
  1737.     in    a,(B_ctl)        ;assure we are talking to ch 0
  1738.     ld    a,5
  1739.     out    (B_ctl),a        ; ready to write WR5
  1740.     ld    a,(B_WR5)        ; get memory copy
  1741.     xor    BLED            ; [JDZ]
  1742.     out    (B_ctl),a        ; Actually turn off CON LED now...
  1743.     ld    (B_WR5),a        ; update memory copy
  1744.     pop    af
  1745.     ret
  1746.  
  1747. ; SIO Initialize data.
  1748. a_init:
  1749.     db    18h,4,20h,1,1bh,7,7eh,5,ALEDoff,3,0c9h    ;For Modem
  1750. a_size    equ    $-a_init
  1751.  
  1752. b_init:                            ;[JDZ] For TTY
  1753.     db    18h,4,44h,2,I_Vector mod 256,3,Auto_Enable,5,BLEDoff,1,1fh
  1754. b_size    equ    $-b_init
  1755.  
  1756.  
  1757. ;This is the data area which gets blasted into RAM upon startup: [JDZ]
  1758. data_init:
  1759.  
  1760. TXdelay        equ    Free_RAM - data_init + $
  1761.         db    33        ; TX delay default is 330 ms
  1762. Persistence        equ    Free_RAM - data_init + $
  1763.         db    63        ; default value for Persistence
  1764. SlotTime        equ    Free_RAM - data_init + $
  1765.         db    5        ; and Slot Time defaults to 50 ms
  1766. TailTime        equ    Free_RAM - data_init + $
  1767.         db    3        ; (should be 11 for 300 baud)
  1768.                     ; Tail Timer default
  1769. Full_Duplex        equ    Free_RAM - data_init + $
  1770.         db    0        ;not Full Duplex to start
  1771. CTS_Control        equ    Free_RAM - data_init + $
  1772.         db    0        ;not CTS Control to start
  1773. Soft_DCD        equ    Free_RAM - data_init + $
  1774.         db    1        ;not Soft DCD to start
  1775.  
  1776. RX_State        equ    Free_RAM - data_init + $
  1777.         db    0        ;Means we are in Recieving State
  1778. RX_Allocated_Buffer    equ    Free_RAM - data_init + $
  1779.         db    0        ;set non-zero if we're in RX state
  1780. RX_buf            equ    Free_RAM - data_init + $
  1781.         dw    0        ;address of current Receive buffer
  1782. RX_head            equ    Free_RAM - data_init + $
  1783.         dw    0        ;address of 1st RX buffer
  1784. RX_Flushing        equ    Free_RAM - data_init + $
  1785.         db    0        ;is non-0 if we ran out of buffer
  1786.                     ;space and are currently flushing this
  1787.                     ;frame being received.  Used by
  1788.                     ;ia_rca and reset by ia_ext.
  1789.  
  1790. TX_State        equ    Free_RAM - data_init + $
  1791.         db    0        ;TX state.
  1792.                     ;0 : we're not in TX state
  1793.                     ;1 : we're in slot time state
  1794.                     ;2 : we're in TX delay state
  1795.                     ;3 : we're in waiting CTS is turn on
  1796.                     ;4 : we're in Transmit data state
  1797.                     ;5 : we're in Tail time state
  1798. TX_Started        equ    Free_RAM - data_init + $
  1799.         db    0        ;non-zero if we've begun TXing chars
  1800. TX_Outstanding        equ    Free_RAM - data_init + $
  1801.         db    0        ;Number of TX CBufs queued up for TX
  1802. TX_Head_CBuf        equ    Free_RAM - data_init + $
  1803.         dw    TX_Top    ;Current active CBuf entry (if active)
  1804. TX_Tail_CBuf        equ    Free_RAM - data_init + $
  1805.         dw    TX_Top    ;next free CBuf entry
  1806. TX_Chain_Head        equ    Free_RAM - data_init + $
  1807.         dw    0        ;holds address of the current buffer
  1808.                     ;chain head that we are transmitting
  1809. TX_Timer        equ    Free_RAM - data_init + $
  1810.         db    0
  1811.  
  1812. A_RR0        equ    Free_RAM - data_init + $
  1813.         db    CTS
  1814. A_WR5        equ    Free_RAM - data_init + $
  1815.         db    ALEDoff        ;state of STA LED & RTS (PTT) line,
  1816.                     ;mainly... (For Ch A only [modem] )
  1817. B_WR5        equ    Free_RAM - data_init + $
  1818.         db    BLEDoff
  1819. ;these next two are used by the IB_TBE interrupt routine.
  1820. Out_esc_mode        equ    Free_RAM - data_init + $
  1821.         db    0        ; not in escaped mode 
  1822. Out_char        equ    Free_RAM - data_init + $
  1823.         ds    1        ; next char to send if escaped mode
  1824. in_break        equ    Free_RAM - data_init + $
  1825.         db    0        ; non-zero if we are in a break detect
  1826.                     ; sequence on the async port
  1827. In_Buffer        equ    Free_RAM - data_init + $
  1828.         dw    0        ;addr of current Input buffer
  1829. In_Head            equ    Free_RAM - data_init + $
  1830.         dw    0        ;addr of 1st Input Buffer
  1831. In_Allocated_Buffer    equ    Free_RAM - data_init + $
  1832.         db    0        ;is not 0 if we've already alloc'd buf
  1833. In_State        equ    Free_RAM - data_init + $
  1834.         db    1        ;convert back to 1 in v.32 code
  1835.                     ;input state machine state
  1836.                     ;4 Mar 8: Make it 0 (from 1) becuz
  1837.                     ;noise on line is first triggering the
  1838.                     ;code to assume that a frame is coming
  1839.                     ;from the host.....  Comment below was
  1840.                     ;appropriate before
  1841.                     ;assume that we've seen an FEND from
  1842.                     ;(non-existent) "previous" frame. This
  1843.                     ;means that when we are receiving data
  1844.                     ;from user, there need be ONLY the
  1845.                     ;FEND char at the end of a frame, and
  1846.                     ;not at the beginning (although if a
  1847.                     ;FEND is at the beginning, it is 
  1848.                     ;ignored.)
  1849. Out_Started        equ    Free_RAM - data_init + $
  1850.         db    0        ;Output not started yet (Logical var)
  1851. Out_Head_CBuf        equ    Free_RAM - data_init + $
  1852.         dw    Out_Top        ;address of buffer to be output rs232
  1853. Out_Tail_CBuf        equ    Free_RAM - data_init + $
  1854.         dw    Out_Top        ;pointer to next free output buffer
  1855. Out_Chain_Head        equ    Free_RAM - data_init + $
  1856.         dw    0        ;addr of buffer we are now outputting
  1857. free            equ    Free_RAM - data_init + $
  1858.         dw    Bottom        ;address of 1st buffer on free list
  1859.  
  1860. data_size    equ    $-data_init
  1861.  
  1862. Out_Address    equ    free+2        ;address of output following data
  1863.         ;ds    1
  1864.  
  1865. buffer_area    equ    Out_Address+1
  1866.  
  1867. TX_Top        equ    buffer_area    ;"top" of output circular buffer
  1868.                     ; 255 out buffer chains pending, max
  1869. TX_Bottom    equ    TX_Top+2*255    ;"bottom" of output circular buffer
  1870.  
  1871.  
  1872. Out_Top        equ    TX_Bottom+2
  1873. Out_Bottom    equ    Out_Top+2*255
  1874.  
  1875.  
  1876. Bottom        equ    Out_Bottom+2    ;end of all code & predefined data
  1877.  
  1878. ;***************************************************************************
  1879.  
  1880. ;    out = to TTY port; in = from TTY port
  1881. ;    TX = to modem; RX = from modem
  1882. ;
  1883. ;    ; means that that code executes without interrupts enabled (except
  1884. ;        for the initialization code)
  1885.  
  1886.     end    start
  1887.